RETURN expression;

带表达式的 RETURN 会终止函数， 并把 expression 的值返回给调用者。 这种形式用于不返回集合的 PL/pgSQL 函数。

在返回标量类型的函数中，表达式的结果会像赋值时描述的那样 被自动转换为函数的返回类型。但要返回复合（行）值， 必须书写一个恰好交付所需列集合的表达式。 这可能需要使用显式转换。

如果你用输出参数声明了函数，只需书写不带表达式的 RETURN。输出参数变量的当前值将被返回。

如果把函数声明为返回 void， 可以使用 RETURN 语句提前退出函数； 但不要在 RETURN 后面写表达式。

函数的返回值不能处于未定义状态。如果控制流到达函数顶层块的末尾 而没有遇到 RETURN 语句，将发生运行时错误。 不过，这一限制不适用于带输出参数的函数和返回 void 的函数。在这些情况下，如果顶层块执行完毕， 会自动执行一条 RETURN 语句。

一些示例：

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

当 PL/pgSQL 函数被声明为返回 SETOF sometype 时， 要遵循的过程略有不同。在这种情况下，要返回的各个项 由一系列 RETURN NEXT 或 RETURN QUERY 命令指定， 然后用一条不带参数的最终 RETURN 命令 表明函数已执行完毕。RETURN NEXT 既可以用于标量数据类型，也可以用于复合数据类型； 对于复合结果类型，将返回一个完整的“表”的结果。 RETURN QUERY 把执行一个查询的结果 追加到函数的结果集中。RETURN NEXT 与 RETURN QUERY 可以在一个集合返回函数中 自由混合使用，此时它们的结果会被拼接起来。

RETURN NEXT 和 RETURN QUERY 实际上并不从函数返回 —— 它们只是把零行或多行追加到函数的结果集中。 然后执行继续进行到 PL/pgSQL 函数中的 下一条语句。随着一条条 RETURN NEXT 或 RETURN QUERY 命令被执行，结果集逐渐构建起来。 最后一条不带参数的 RETURN 会使控制流退出函数（或者你也可以直接让控制流到达函数末尾）。

RETURN QUERY 有一个变体 RETURN QUERY EXECUTE， 它指定要动态执行的查询。参数表达式可以通过 USING 插入计算得到的查询字符串中， 方式与 EXECUTE 命令完全相同。

如果你用输出参数声明了函数，只需书写不带表达式的 RETURN NEXT。每次执行时， 输出参数变量的当前值都会被保存，最终作为结果的一行返回。 注意，当有多个输出参数时必须把函数声明为返回 SETOF record；当只有一个 sometype 类型的输出参数时， 声明为返回 SETOF sometype， 这样才能创建带输出参数的集合返回函数。

下面是一个使用 RETURN NEXT 的函数示例：

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

下面是一个使用 RETURN QUERY 的函数示例：

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 语句是 IF 最简单的形式。THEN 与 END IF 之间的语句会在条件为真时被执行。 否则它们将被跳过。

示例：

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 语句对 IF-THEN 做了扩展， 允许你指定一组在条件不为真时应当执行的备选语句。 （注意，这包括条件求值为 NULL 的情况。）

示例：

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有时备选项不止两个。IF-THEN-ELSIF 提供了一种依次检查多个备选项的便捷方法。 各个 IF 条件会被依次测试， 直到找到第一个为真的条件。然后执行与之关联的语句， 之后控制流传递到 END IF 之后的下一条语句。 （后续的 IF 条件不会再被测试。） 如果没有任何 IF 条件为真， 则执行 ELSE 块（如果有）。

下面是一个示例：

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

关键字 ELSIF 也可以拼写成 ELSEIF。

完成同一任务的另一种方法是嵌套 IF-THEN-ELSE 语句，如下例所示：

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

不过，这种方法要求为每个 IF 写一个匹配的 END IF， 因此当备选项较多时，它比使用 ELSIF 繁琐得多。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的简单形式基于操作数相等提供条件执行。 search-expression 会被求值（一次）， 并依次与各 WHEN 子句中的 expression 比较。 如果找到匹配，则执行对应的 statements，随后控制流传递到 END CASE 之后的下一条语句。 （后续的 WHEN 表达式不会再被求值。） 如果没有找到匹配，则执行 ELSE 的 statements； 但如果 ELSE 不存在， 将引发 CASE_NOT_FOUND 异常。

下面是一个简单的示例：

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的搜索形式基于布尔表达式的真假提供条件执行。 各 WHEN 子句的 boolean-expression 会被依次求值， 直到发现一个结果为 true 的表达式。 然后执行对应的 statements， 随后控制流传递到 END CASE 之后的下一条语句。 （后续的 WHEN 表达式不会再被求值。） 如果没有发现为真的结果，则执行 ELSE 的 statements； 但如果 ELSE 不存在， 将引发 CASE_NOT_FOUND 异常。

下面是一个示例：

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

这种形式的 CASE 与 IF-THEN-ELSIF 完全等价， 区别在于一条规则：到达被省略的 ELSE 子句 会导致错误，而不是什么都不做。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定义一个无条件循环，它会无限重复， 直到被 EXIT 或 RETURN 语句终止。可选的 label 可以被嵌套循环中的 EXIT 和 CONTINUE 语句用来指明这些语句针对哪个循环。

EXIT [ label ] [ WHEN boolean-expression ];

如果没有给出 label， 则终止最内层循环，并接着执行 END LOOP 之后的语句。如果给出了 label，它必须是当前层或某个外层的 嵌套循环或块的标签。此时被指名的循环或块会被终止， 控制流继续进行到该循环/块对应 END 之后的语句。

如果指定了 WHEN，则只有当 boolean-expression 为真时才会退出循环。 否则，控制流传递到 EXIT 之后的语句。

EXIT 可以用于所有类型的循环； 它并不仅限于无条件循环。

当与 BEGIN 块一起使用时， EXIT 会把控制流传递到块结束之后的下一条语句。 注意，为此目的必须使用标签；不带标签的 EXIT 永远不会被认为匹配一个 BEGIN 块。（与 8.4 之前的 PostgreSQL 版本不同， 那些版本允许不带标签的 EXIT 匹配一个 BEGIN 块。）

示例：

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果没有给出 label， 则开始最内层循环的下一次迭代。也就是说， 循环体中所有剩余的语句都被跳过， 控制流返回循环控制表达式（如果有）， 以决定是否需要再一次循环迭代。 如果存在 label， 它指明将继续执行哪个循环。

如果指定了 WHEN，则只有当 boolean-expression 为真时 才开始循环的下一次迭代。否则， 控制流传递到 CONTINUE 之后的语句。

CONTINUE 可以用于所有类型的循环； 它并不仅限于无条件循环。

示例：

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

WHILE 语句会在 boolean-expression 求值为真的情况下重复一系列语句。 该表达式会在每次进入循环体之前被检查。

例如：

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

这种形式的 FOR 创建一个遍历整数范围的循环。 变量 name 被自动定义为 integer 类型，并且只存在于循环内部 （该变量名的任何现有定义在循环内都会被忽略）。 给出范围下界和上界的两个表达式在进入循环时各求值一次。 如果未指定 BY 子句，迭代步长为 1； 否则步长是 BY 子句中指定的值， 该值同样在进入循环时求值一次。 如果指定了 REVERSE， 那么每次迭代之后是减去步长值，而不是加上。

一些整数 FOR 循环的示例：

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下界大于上界（在 REVERSE 的情况下 是小于），则循环体完全不会被执行。不会引发任何错误。

如果 FOR 循环上附加了 label，则整数循环变量 可以用该 label 以限定名的形式引用。

异常处理程序经常需要识别所发生的具体错误。 在 PL/pgSQL 中获取当前异常信息 有两种方式：特殊变量和 GET STACKED DIAGNOSTICS 命令。

在异常处理程序内部，特殊变量 SQLSTATE 包含与被引发异常对应的错误代码 （可能的错误代码列表见 Table A.1）。 特殊变量 SQLERRM 包含与该异常关联的错误消息。 这些变量在异常处理程序之外是未定义的。

在异常处理程序内部，还可以使用 GET STACKED DIAGNOSTICS 命令检索 当前异常的信息，其形式为：

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每个 item 是一个关键字， 标识要赋给指定 variable （其数据类型应适合接收该值）的状态值。 当前可用的状态项见 Table 41.2。

如果异常没有为某个状态项设置值，将返回一个空字符串。

下面是一个示例：

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;